F: Wie kann ich die Einschußlöcher von hit_hole in die Wände bekommen, egal wie weit diese vom Spieler fort sind?
A: Das Loch erscheint nur dann an der Wand, wenn die Kugel so weit kommt. Setzen Sie die _bulletspeed für Ihre Waffe in der weapons.wdl nach oben.
action weap_mg_animated
{
MY.__ROTATE = ON;
MY.__REPEAT = ON;
MY.__BOB = ON;
MY._OFFS_X = 45;
MY._OFFS_Y = 15;
MY._OFFS_Z = 15;
MY._AMMOTYPE = 1.99;
if (MY._WEAPONNUMBER == 0) { MY._WEAPONNUMBER = 2; }
MY._BULLETSPEED = 5000.01;
MY._FIRETIME = 2;
MY._FIREMODE = DAMAGE_SHOOT + HIT_HOLE + GUNFX_BRASS + GUNFX_ANIMATE + 0.20;
gun();
}

F: Wie kann ich das Fadenkreuz am Anfang des Spiels sichtbar machen, ohne erst "K" drücken zu müssen?
A: Schreiben Sie diese Zeile an das Ende der Main Funktion:

pan_cross_toggle();

F: Ich habe mich gefragt, ob ich die Datei eines Models ändern kann, je nachdem welche Auflösung gewählt ist, um die Frame Rate auf langsameren Rechnern zu verbessern.
A: Machen Sie es so:

string high_poly = <highpoly.mdl>;

action my_model // low poly model
{
if (video_mode >= 8)
{
ent_morph (my, high_poly);
}
....................
}

F: Wie kann ich ein flackerndes Licht erstellen?
A: Hier ist ein Beispiel für ein Feuer:

action flickering_light
{
d3d_lightres = on;
while (1)
{
my.lightrange = 70 + random(30);
my.lightred = 150 + random(100);
my.lightgreen = 150;
my.lightblue = 50;
waitt (2);
}
}

Fire.avi (586 Kb, divx 5.01)

F: Wie kann ich die Geschwindigkeit des Spielers erhöhen oder senken?
A: Öffnen Sie movement.wdl, suchen Sie die folgenden Zeilen und ändern Sie die Werte:

var strength[3] = 5,4,75; // default ahead, side, jump strength
var astrength[3] = 7,5,2; // default pan, tilt, roll strength

F: Ich möchte die Bitmap eines Panels zur Laufzeit ändern. Geht das?
A: Benutzen Sie diesen Code:

bmap first_pcx = <first.pcx>;
bmap second_pcx = <second.pcx>;

panel my_pan
{
bmap = first_pcx;
pos_x = 0;
pos_y = 0;
flags = refresh, d3d, visible;
}

function change_bitmap()
{
my_pan.bmap = second_pcx;
}

on_q change_bitmap;

F: Wie kann ich unbegrenzte Munition für eine meiner Waffen erhalten?
A: Schreiben Sie diese Zeilen an das Ende Ihrer Main Funktion

while (1)
{
if (ammo1 < 50) {ammo1 = 50;}
wait (1);
}

und Sie erhalten unbegrenzt Munition für jede Waffe, die ammo1 benutzt (weapon_mg_animated, etc.)

F: Wie mache ich den Spieler für 20 Sekunden unverwundbar?
A: Fügen Sie diesen Code an das Ende Ihrer office.wdl an:

function invulnerability()
{
player.event = null;
sleep (20);
player.event = fight_event;
}

on_i = invulnerability; // I = invulnerability

F: Wie kann ich einem Spieler im Multiplayer einen Namen geben?
A: Starten Sie das Spiel mit der Kommandozeile "-pl Ihr_Name".

Sie können den Namen des Clients mit einer einfachen Definition sehen:

text player_txt
{
font = _a4font;
pos_x = 0;
pos_y = 100;
string = player_name;
flags = visible;
}